10 FORR=241TO253:READM:POKER,M:NEXT
 20 DATA162,255,232,169,32,157,0,208,224,255,208,246,96
 30 GOSUB1670:PRINT"CRAZY-EIGHTS"
 100 REM COPYRIGHT PROGRESSIVE COMPUTING 1979
 110 DIMD(52),H(52),LO(4),OL(4),S(4)
 120 S(1)=230:S(2)=232:S(3)=229:S(4)=231 
 130 OL(1)=53382:OL(2)=53574:OL(3)=53766:OL(4)=53958
 140 SU$="CLUBS   DIAMONDSHEARTS  SPADES  "
 150 U$="CDHS":C1$="A23456789TJQK"
 160 FORX=1TO4:LO(X)=OL(X):NEXT
 170 PRINT"ENTER CARD NAMES AS VALUE FOLLOWED BY SUIT
 180 PRINT"VALUES ARE:2=2" 
 190 PRINTTAB(11)"TO":PRINTTAB(11)"9=9"
 200 PRINTTAB(11)"TEN=T":PRINTTAB(11)"JACK=J"
 210 PRINTTAB(11)"QUEEN=Q":PRINTTAB(11)"KING=K"
 220 PRINTTAB(11)"ACE=A"
 230 PRINT"SUITS ARE:"
 240 PRINTTAB(11)"CLUBS=C":PRINTTAB(11)"DIAMONDS=D"
 250 PRINTTAB(11)"HEARTS=H":PRINTTAB(11)"SPADES=S"
 260 PRINT"IF YOU CAN'T PLAY ENTER 'N'"
 270 INPUT"READY";Z9$:GOSUB1670
 280 D1=52:FORX=1TO52:D(X)=-1:H(X)=0:NEXTX
 290 FORI=1TO7:GOSUB1400:H(FD)=1:GOSUB1400:H(FD)=-1:NEXTI
 300 GOSUB1400:I=FD:GOSUB1450:D$=MID$(C1$,IC,1):H1=7:H2=7:B=0
 310 L$="FIRST CARD IS":LO=53557:GOSUB1550
 320 LO=53688:GOSUB1480:C$=MID$(C1$,IC,1)+MID$(U$,IS,1)
 330 GOSUB1450:IFIC=11THENGOSUB1130
 340 IFIC=2THENFORX=1TOIC:GOSUB1400:H(FD)=1:H1=H1+1:NEXTX
 350 IFIC=2THENGOSUB1130
 360 IFH2=0ORB=2THEN390
 370 GOSUB690:FORX=1TO4:LO(X)=OL(X):NEXT
 380 IFH1<>0ANDB<>2THENGOSUB1130:GOTO360
 390 C1=0:C2=0
 400 IFH2<>0THENPRINT"CARDS LEFT IN MY HAND"
 410 FORX=1TO14:PRINT:NEXT:LO=53766
 420 CN=0:FORI=1TO52
 430 IFH(I)=-1THENGOSUB1450:D$=MID$(C1$,IC,1):CN=CN+1
 440 IFCN=9ANDH(I)=-1THENLO=LO+128
 450 IFIC>10THENIC=10
 460 IFH(I)=-1THENC1=C1+IC
 470 IFH(I)=-1THENFORY=LO+32TOLO+128STEP32:POKEY,32:NEXTY
 480 IFH(I)=-1THENGOSUB1480:LO=LO+2
 490 NEXTI:PRINT
 500 FORI=1TO52:IFH(I)=1THENGOSUB1450:IFIC>10THENIC=10
 510 IFH(I)=1THENC2=C2+IC
 520 NEXTI
 530 IFC1=0THEN560
 540 IFC1>=C2THENC1=C1-C2:C2=0:GOTO560
 550 C2=C2-C1:C1=0
 560 S1=S1+C1:S2=S2+C2
 570 PRINT"YOUR SCORE IS ";C1:PRINT"MY SCORE IS ";C2
 580 IFC2<C1THENPRINT"YOU WON THAT HAND":N1=N1+1:GOTO600
 590 PRINT"I WON THAT HAND":N2=N2+1
 600 PRINT"YOUR TOTAL =";S1
 610 PRINT:PRINT"MY TOTAL=";S2
 620 PRINT:N3=N3+1:INPUT"PLAY AGAIN";Z9$
 630 IFASC(Z9$)=89THENGOSUB1670:GOTO280
 640 PRINT:PRINT"OUT OF "N3;"HANDS YOU ";
 650 PRINT"WON";N1:PRINT"YOUR TOTAL IS";S1:PRINT"MINE IS";S2
 660 IFS1>S2THENPRINT"YOU WON-BUT WAIT TILL NEXT TIME!"
 670 IFS2>S1THENPRINT"I AM THE GREATEST!"
 680 END
 690 FORI=1TO52
 700 IFH(I)=1THENGOSUB1450:D$=MID$(C1$,IC,1):GOSUB1460
 710 NEXTI
 720 L$="PLAY A CARD ?":LO=53557:GOSUB1550  
 725 Z9$=""
 727 GOSUB1530:Z9$=Z9$+CHR$(PEEK(531)) 
 730 IFZ9$<>"N"ANDLEN(Z9$)<2THEN727
 750 L$="              ":LO=53557:GOSUB1550
 760 LO=53558:GOSUB1550
 770 IFLEFT$(Z9$,1)<>"N"ANDRIGHT$(Z9$,1)<>"N"THEN840 
 780 IFD1>0THEN820 
 790 IFB=0THENL$="DECK'S EMPTY  ":LO=53558:GOSUB1550:B=-1
 800 IFB=-1THENB=1:RETURN
 810 L$="YOU'RE BLOCKED":B=B+1:LO=53557:GOSUB1550:RETURN
 820 GOSUB1400:I=FD:H1=H1+1:H(I)=1:GOSUB1450:D$=MID$(C1$,IC,1)
 830 GOSUB1460:GOTO720
 840 FORI=1TO52:GOSUB1450
 850 IFZ9$=MID$(C1$,IC,1)+MID$(U$,IS,1)THEN880
 860 NEXTI
 870 L$="NOT A CARD  ":LO=53558:GOSUB1550:GOTO720
 880 IN=0:IFMID$(U$,IS,1)=RIGHT$(C$,1)THENIN=1
 890 IFMID$(C1$,IC,1)="8"THENIN=1
 900 IFLEFT$(Z9$,1)=MID$(C$,1,1)THENIN=1
 910 IFIN=0THENL$="  ILLEGAL   ":LO=53558:GOSUB1550:GOTO720
 920 NH=0
 930 IFH(I)<>1THENL$="CHEATER  ":LO=53558:GOSUB1550:GOTO720
 940 H(I)=0:C$=MID$(C1$,IC,1)+MID$(U$,IS,1):H1=H1-1
 950 D$=MID$(C1$,IC,1):LO=53688:GOSUB1480
 960 FLG=0
 970 IFMID$(C$,1,1)<>"8"THENB=0:FLG=1
 980 IFFLG=1THENGOSUB1450:GOSUB1570
 990 L$="                 ":LO=53564:GOSUB1550
 1000 LO=53556:GOSUB1550
 1010 IFIC=11ORIC=2THENFORX=1TO4:LO(X)=OL(X):NEXT
 1020 IFIC=2ANDD1>1THENFORX=1TOIC:GOSUB1400:H(FD)=-1:H2=H2+1
 1030 IFIC=2ANDD1>0THENNEXTX:GOTO690
 1040 IFIC=2THEN690
 1050 IFIC=11ANDH1>0THEN690
 1060 IFFLG=1THENRETURN
 1070 L$="WHAT SUIT ?":LO=53558:GOSUB1550  
 1075 S9$="":GOSUB1530:S9$=CHR$(PEEK(531))
 1100 FORI=1TO4:IFS9$=MID$(U$,I,1)THENC$=" "+MID$(U$,I,1):B=0
 1110 NEXTI:GOSUB1670:RETURN
 1120 NEXTI:L$="NOT A SUIT":LO=53558:GOSUB1550 :GOTO1070
 1130 FORI=52TO1STEP-1:GOSUB1450
 1140 IFH(I)=-1ANDMID$(C1$,IC,1)<>"8"THEN1160
 1150 GOTO1180
 1160 IFMID$(U$,IS,1)=RIGHT$(C$,1)THEN1250
 1170 IFMID$(C1$,IC,1)=LEFT$(C$,1)THEN1250
 1180 NEXTI
 1190 FORI=29TO32:IFH(I)=-1THEN1250
 1200 NEXTI
 1210 IFD1>0THEN1240
 1220 IFB=0THENL$="DECK'S EMPTY  ":LO=53564:GOSUB1550
 1230 L$="I'M BLOCKED  ":LO=53564:B=B+1:GOSUB1550:RETURN
 1240 GOSUB1400:H(FD)=-1:H2=H2+1:GOTO1130
 1250 GOSUB1450:D$=MID$(C1$,IC,1):LO=53688:GOSUB1480
 1260 C$=MID$(C1$,IC,1)+MID$(U$,IS,1):B=0:H(I)=0:H2=H2-1
 1270 H2$=STR$(H2)
 1280 L$="I HAVE"+H2$+" CARDS ":LO=53563:GOSUB1550
 1290 IFIC=11ANDH2>0THEN1130
 1300 IFIC=2ANDD1>1THENFORX=1TOIC:GOSUB1400:H(FD)=1:H1=H1+1
 1310 IFIC=2ANDD1>0THENNEXTX:GOTO1130
 1320 IFIC=2THEN1130
 1330 IFLEFT$(C$,1)<>"8"THENRETURN
 1340 FORJ=1TO4:Y(J)=0:NEXTJ
 1350 FORJ=1TO4:FORK=JTO52STEP4:IFH(K)=-1THENY(J)=Y(J)+1
 1360 NEXTK,J
 1370 P=1:FORJ=2TO4:IFY(J)>Y(P)THENP=J
 1380 NEXTJ:C$=" "+MID$(U$,P,1):S1$=MID$(SU$,(P-1)*8+1,8)
 1390 L$="SUIT IS "+S1$:LO=53564:GOSUB1550:RETURN
 1400 K=INT(RND(1)*52+1):FORK1=KTO52:IFD(K1)=-1THEN1440
 1410 NEXTK1
 1420 FORK1=1TOK-1:IFD(K1)=-1THEN1440
 1430 NEXTK1
 1440 D(K1)=0:FD=K1:D1=D1-1:RETURN
 1450 IS=(I-INT((I-1)/4)*4):IC=INT((I-1)/4)+1:RETURN
 1460 LO=LO(IS):LO(IS)=LO(IS)+2
 1470 FORX=LO(IS)+30TOLO(IS)+126STEP32:POKEX,32:NEXT
 1480 FORX=LOTOLO+1:POKEX,131:POKEX+160,132:NEXT
 1490 FORX=LO+31TOLO+127STEP32:POKEX,140:POKEX+3,139:NEXT
 1500 POKELO-1,221:POKELO+2,222:POKELO+159,220:POKELO+162,223
 1510 POKELO+64,S(IS)
 1520 POKELO+32,ASC(MID$(D$,1,1)):RETURN
 1530 POKE11,0:POKE12,253  
 1540 X=USR(X):RETURN
 1550 FORX=1TOLEN(L$):POKELO+32*X,ASC(MID$(L$,X,1)):NEXT
 1560 FORX=1TO500:NEXT:RETURN
 1570 LO(IS)=OL(IS)
 1580 FORY=1TO7
 1590 LO=LO(IS)
 1600 FORX=LOTOLO+1:POKEX,32:POKEX+160,32:NEXT
 1610 FORX=LO+31TOLO+127STEP32:POKEX,32:POKEX+3,32:NEXT
 1620 POKELO-1,32:POKELO+2,32:POKELO+159,32:POKELO+162,32
 1630 POKELO+64,32
 1640 POKELO+32,32
 1650 LO(IS)=LO(IS)+2
 1660 NEXTY:RETURN
 1670 D=208:POKE11,241:POKE12,0
 1680 X=USR(X)
 1690 POKE248,D:D=D+1:IFD<213THEN1680
 1700 RETURN