10 DIMC(52):PRINT"BLACK JACK"
 20 PRINT"TYPE ONE OF THE FOLLOWING WHEN ASKED"
 30 PRINTTAB(5)"'H'...TO HIT ME"
 40 PRINTTAB(5)"'S'...TO STAY":PRINTTAB(5)"'D'...TO DOUBLE"
 50 PRINT:PRINT"There are two sure wins"
 60 PRINT"ONE-get 21 in two cards"
 70 PRINT"TWO-draw five cards without going over 21"
 80 PRINT"The other way to win is to beat the computers hand"
 90 PRINT"and not go over 21"
 100 PRINT"Payoff is 1.5 times your bet on a natural or sure win
 110 PRINT"otherwise it's even."
 120 PRINT:PRINT"Maximum bet is $ 1000"
 130 FORI=1TO4:S(I)=228+I:NEXT:S(0)=63
 140 PRINT:INPUT"number of players(1-3)";N
 150 IFN<>INT(N)ORN<1ORN>3THEN140
 160 D=53:POKE530,1:FORI=1TO52:C(I)=I:NEXT
 170 P(1)=53382:P(2)=53574:P(3)=53766:P(4)=53958
 180 REM COPYRIGHT PROGRESSIVE COMPUTING
 190 FORI=1TON+1:FORJ=1TO5:PC(I,J)=0:NEXTJ:SW(I)=0:NEXTI
 200 PRINT:PRINT"Enter your wagers":FORI=1TON
 210 S=0:PRINT"Player"I;:INPUTW(I)
 220 IFW(I)<0ORW(I)>1000THEN210
 230 IFW(I)<>INT(W(I))THENPRINT"No pennies please!":GOTO210
 240 NEXT:FORI=1TO30:PRINT:NEXT:POKE55104,32
 250 FORI1=1TO2:FORQ=1TON+1
 260 GOSUB880:LO=P(Q):IFI1=1ANDQ=N+1THENS=1:CS=IS
 270 PC(Q,I1)=IC:GOSUB800:P(Q)=P(Q)+3:NEXTQ
 280 S=0:NEXTI1
 290 S=0:FORQ=1TON+1:GOSUB1030:IFT=21THENGOSUB1070
 300 IFT=21ANDQ=N+1THENGOSUB1110:GOTO600
 310 NEXTQ
 320 FORQ=1TON:I1=3:IFSW(Q)=1THEN440
 330 IFQ=N+1THEN450
 340 L$="PLAYER"+STR$(Q)+"?":GOSUB1080
 350 POKE57100,247:C=255-PEEK(57100)
 360 IFC=128ORC=8THEN390
 370 IFC=64THENW(Q)=W(Q)*2:GOTO390
 380 GOTO350
 390 L$="         ":GOSUB1080:IFC=128THEN440
 400 GOSUB880:PC(Q,I1)=IC:LO=P(Q):GOSUB800:P(Q)=P(Q)+3
 410 GOSUB1030:IFT>21THENL$="BUSTED!!!":GOSUB1080:GOTO440
 420 IFI1=5THENSW(Q)=1:GOTO440
 430 I1=I1+1:GOTO340
 440 NEXTQ
 450 Q=N+1:GOSUB1110:LO=P(Q)+6:I1=3:GOSUB1030
 460 TL=0:TW=0:FORQ=1TON:TL(Q)=0:TW(Q)=0:PT(Q)=0:NEXTQ
 470 IFT<17THEN550
 480 IFT>16THENCT=T:FORQ=1TON:GOSUB1030:PT(Q)=T
 490 IFSW(Q)=1ORPT(Q)>21THEN530
 510 IFCT=PT(Q)ORCT>PT(Q)THENTW=TW+W(Q)
 520 IFCT<PT(Q)THENTL=TL+W(Q)
 530 NEXTQ
 540 IFTL=0ORCT>15ANDTW>=TL/2+1THEN590
 550 Q=N+1:IFI1=6THENSW(N+1)=1:GOTO600
 560 GOSUB880:PC(Q,I1)=IC:LO=P(Q):GOSUB800:P(Q)=P(Q)+3
 570 GOSUB1030:IFT<22THENI1=I1+1:GOTO460
 580 L$="BUSTED!!!":GOSUB1080
 590 FORI=1TO2000:NEXT
 600 FORI=55168TO55300:POKEI,32:NEXT:FORI=1TO30:PRINT:NEXT
 610 FORI=1TON:H(I)=H(I)-W(I):NEXT
 620 IFSW(I)=0THEN640
 630 PRINT"THE HOUSE WINS (again)!!":GOTO750
 640 PRINT"Congratulations to:":PRINT
 650 S=0:FORI=1TON:IFSW(I)=0GOTO670
 660 PRINT"  Player"I:H(I)=H(I)+W(I)*2.5:S=1
 670 NEXT
 680 Q=N+1:GOSUB1030:CT=T
 690 FORQ=1TON:GOSUB1030:IFCT<22ANDT<CT+1THEN730
 700 IFSW(Q)=1THEN730
 710 IFT>21THEN730
 720 PRINT"  Player"Q:H(Q)=H(Q)+W(Q)*2:S=1
 730 IFQ<NTHENNEXTQ
 740 IFS=0THENPRINT"THE HOUSE!"
 750 PRINT:PRINT:PRINT
 760 Q=N+1:GOSUB1030:PRINT"The house had"T:PRINT:PRINT
 770 FORQ=1TON:GOSUB1030
 780 PRINT"Player"Q,"Had "T,"Wagered"W(Q),"Now has $"H(Q):NEXT
 790 GOTO170
 800 FORI=LOTOLO+1:POKEI,131:POKEI+160,132:NEXT
 810 FORI=LO+31TOLO+127STEP32:POKEI,140:POKEI+3,139:NEXT
 820 POKELO-1,221:POKELO+2,222:POKELO+159,220:POKELO+162,223
 830 IFS=1THENCC=187:GOTO1150
 840 POKELO+32,ASC(MID$(C$,1,1))
 850 POKELO+64,S(IS)
 870 RETURN
 880 IFC=128THENFORZ=1TOINT(C/7):XX=RND(1):NEXT
 890 IFC=8THENFORZ=1TOC:XX=RND(1):NEXT
 900 IFC=64THENFORZ=1TOINT(C/5.5):XX=RND(1):NEXT
 910 D=D-1:IFD<1THENL$="newdeck":GOSUB1080:D=53:FORI=1TO52
 920 IFD=53THENC(I)=I:NEXTI:L$="       ":GOSUB1080:GOTO910
 930 X=INT(D*RND(1)+1):H1(Q,I1)=C(X):C(X)=C(D)
 940 Z1=INT((H1(Q,I1)-1)/13):Z2=H1(Q,I1)-1-Z1*13
 950 IS=Z1+1:IC=Z2+1
 960 C$=MID$(STR$(IC),2):IFIC=1THENC$="A"
 970 IFIC=10THENC$="T"
 980 IFIC=11THENC$="J"
 990 IFIC=12THENC$="Q"
 1000 IFIC=13THENC$="K"
 1010 IFIC>10THENIC=10
 1020 RETURN
 1030 IC=0:T=0:FORI=1TO5:IFPC(Q,I)=1THENIC=IC+1
 1040 T=T+PC(Q,I):NEXT:IFIC=0THENRETURN
 1050 FORI=1TOIC:IFT+10>21THENRETURN
 1060 T=T+10:NEXT:RETURN
 1070 L$="BLACKJACK":SW(Q)=1:S=0
 1080 FORI=1TOLEN(L$):POKEP(Q)+I,ASC(MID$(L$,I,1)):NEXT
 1090 IFD<1THENFORX=1TO2000:NEXT:RETURN
 1100 RETURN
 1110 IFQ<>N+1THENRETURN
 1120 LO=P(Q)-6:S=0:IS=CS:IC=PC(Q,1):GOSUB960
 1130 CC=32:GOSUB1150:GOSUB800:RETURN
 1140 GOSUB800:RETURN
 1150 FORY=LO+32TOLO+128STEP32
 1160 FORX=0TO1:POKEY+X,CC:NEXTX,Y:RETURN