10 INPUT"NUMBER OF PLAYERS";N
 20 GOSUB 700
 30 FOR I=1 TO N
 40 PRINT"PLAYER";I;
 50 INPUT"NAME IS";A$(I)
 60 NEXT I
 80 INPUT"Action";I$
 90 Z$=MID$(I$,1,1)
 100 IF Z$="A" THEN GOSUB 600
 110 IF Z$="G" THEN GOSUB 400
 120 IF Z$="P" THEN PRINT:FOR I=1 TO N:PRINT"PLAYER";I;"IS ";A$(I):NEXT
 130 IF Z$="D" THEN GOSUB 800
 380 GOTO 80
 390 GOTO 70
 400 REM PROCESS GUESS
 410 INPUT"WHO'S GUESS";J$
 420 FOR J=1 TO N:IF MID$(A$(J),1,LEN(J$))=J$ GOTO 440
 430 NEXT J:PRINT"NO SUCH NAME":RETURN
 440 INPUT"PERSON,WEAPON,ROOM";A$,B$,C$
 450 RESTORE:FOR A=1 TO 6:READ X$:IF MID$(X$,1,LEN(A$))=A$ GOTO 470
 460 NEXT A:PRINT"NO SUCH PERSON":RETURN
 470 FOR B=A+1 TO 12:READ X$:IF MID$(X$,1,LEN(B$))=B$ GOTO 490
 480 NEXT B:PRINT"NO SUCH WEAPON":RETURN
 490 FOR C=B+1 TO 21:READ X$:IF MID$(X$,1,LEN(C$))=C$ GOTO 510
 500 NEXT C:PRINT"NO SUCH ROOM":RETURN
 510 INPUT"WHO HAD IT";K$
 520 FOR K=1 TO N:IF MID$(A$(K),1,LEN(K$))=K$ GOTO 540
 530 NEXT K:PRINT"NO SUCH PLAYER":RETURN
 540 J=J+1:IF J>N THEN J=1
 550 IF J<>K THEN A(A,J)=NO:A(B,J)=NO:A(C,J)=NO:GOTO 540
 560 G=G+1:IF B(A,K)=0 THEN B(A,K)=G
 570 IF B(B,K)=0 THEN B(B,K)=G
 580 IF B(C,K)=0 THEN B(C,K)=G
 590 RETURN
 600 REM PROCESS ASSIGN
 610 INPUT"WHO,WHAT";J$,I$
 620 FOR J=1 TO N:IF MID$(A$(J),1,LEN(J$))=J$ GOTO 640
 630 NEXT J:PRINT"NO SUCH PLAYER":RETURN
 640 RESTORE:FOR I=1 TO 21:READ X$:IF MID$(X$,1,LEN(I$))=I$ GOTO 660
 650 NEXT I:PRINT"NO SUCH IDEM":RETURN
 660 A(I,J)=ASC("Y")
 670 RETURN
 700 REM INIT MATRIX
 710 DIM A(21,N),B(21,N)
 720 FOR I=1 TO 21
 730 FOR J=1 TO N
 740 A(I,J)=ASC(".")
 750 B(I,J)=0
 760 NEXT J:NEXT I
 770 T=13:IF N>4 THEN T=10:IF N=5 THEN T=12
 780 NO=ASC("N")
 790 RETURN
 800 REM SET UP DISPLAY
 810 PRINT"Player No.";
 820 PRINT TAB(T);" ";
 830 FOR J=1 TO N
 840 PRINT CHR$(J+48);" ";
 850 NEXT J:PRINT
 900 REM SET UP DISPLAY
 910 RESTORE
 920 FOR I=1 TO 21
 930 IF I=7 OR I=13 THEN PRINT
 940 READ A$:A$=MID$(A$,1,T):PRINT A$;
 950 PRINT TAB(T);" ";
 960 FOR J=1 TO N
 970 X=A(I,J):IF B(I,J)<>0 THEN X=ASC("M")
 980 PRINT CHR$(X);" ";:NEXT J
 990 PRINT:NEXT I:RETURN
 1000 DATA MUSTARD,PLUM,GREEN,PEACOCK,SCARLET,WHITE
 1010 DATA KNIFE,CANDLESTICK,REVOLVER,ROPE,LEAD PIPE,WRENCH
 1020 DATA HALL,LOUNGE,DINING ROOM,KITCHEN,BALL ROOM,CONSERVATORY
 1030 DATA BILLIARD ROOM,LIBRARY,STUDY
 1040 END